Windows Tricks

System Information

Save & rename to *.cmd:

:: RENAME SystemInfo.cmd.txt to SystemInfo.cmd
@echo off
MODE CON: COLS=128
color f4
cls
ipconfig
tracert -4 -d -h 1 %COMPUTERNAME%
GETMAC /V /NH
ECHO.
color f2
systeminfo.exe
ECHO.
color f4
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "$cs = Get-CimInstance Win32_ComputerSystem; $bios = Get-CimInstance Win32_BIOS; $sku = Get-CimInstance Win32_ComputerSystemProduct; [PSCustomObject]@{Model=$cs.Model; Name=$cs.Name; Manufacturer=$cs.Manufacturer; SystemType=$cs.SystemType; SystemSKUNumber=$cs.SystemSKUNumber; BIOSSerialNumber=$bios.SerialNumber} | Format-Table -AutoSize"
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "get-Disk"
VER
ECHO.
color f0
SET /p q=Press Enter to exit:

Win11 mit lokalem Konto

Nach Länder- und Sprachwahl: ⇑ + F10 (CMD-Konsole):
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\OOBE /v BypassNRO /t REG_DWORD /d 1 /f shutdown /r /t 0
Alternativ: ⇑ + F10 (CMD-Konsole):
start ms-cxh:localonly
Nach Reboot, Länder- und Sprachwahl, Weiter ohne Internet …

Win11 ohne System-Prüfung

Save & rename to *.reg:

Windows Registry Editor Version 5.00
; Windows 11 ohne System-Prüfung mit lokalem Konto installieren
; RENAME w11anyway.reg.txt to w11anyway.reg

[HKEY_LOCAL_MACHINE\SYSTEM\Setup\MoSetup]
"AllowUpgradesWithUnsupportedTPMOrCPU"=dword:00000001

[HKEY_LOCAL_MACHINE\SYSTEM\Setup\LabConfig]
"BypassTPMCheck"=dword:00000001
"BypassSecureBootCheck"=dword:00000001
"BypassCPUCheck"=dword:00000001
"BypassRAMCheck"=dword:00000001
"BypassDiskCheck"=dword:00000001
"BypassStorageCheck"=dword:00000001

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\OOBE]
"BypassNRO"=dword:00000001

Alle TrayIcons anzeigen

Save & rename to *.cmd:

:: RENAME ShowAllTrayIcons.cmd.txt to ShowAllTrayIcons.cmd
@echo off
:: Alle bekannten TrayIcons anzeigen (Win10)
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer" /v "EnableAutoTray" /t REG_DWORD /d 0 /f >NUL

:: Alle bekannten TrayIcons anzeigen (Win11)
SET PS="%TEMP%\AllTrayIcons.ps1"
ECHO Get-ChildItem "HKCU:\Control Panel\NotifyIconSettings" ^| ForEach-Object { > %PS%
ECHO   Set-ItemProperty -Path $_.PSPath -Name 'IsPromoted' -Type 'DWORD' -Value 1 >> %PS%
ECHO } >> %PS%
powershell.exe -windowstyle hidden -ExecutionPolicy Bypass -Command %PS%

Boot to UEFI

shutdown /r /fw /f /t 0
oder
+ X, Herunterfahren oder abmelden → Neu starten (mit ⇑ + Klick)
Problembehandlung → Erweiterte Optionen → UEFI-Firmwareeinstellungen

Mount EFI partition

Einbinden = mountvol y: /s
Ausklinken = mountvol y: /d

DiskPart - Partition Manager

CMD (Admin!), dann diskpart

Disks anzeigen = list disk
Disk wählen = select disk 2 (!!!)
Partition anzeigen = list partition
Alle Partitionen löschen = clean
Partition erstellen = create partition primary
EFI-Partition erstellen = create partition efi (→GPT),
dann format quick fs=fat32

WiFi-Export

Save & rename to *.cmd:

:: RENAME WiFi-Export.cmd.txt to WiFi-Export.cmd
@COLOR F1
CLS
MD "%USERPROFILE%\Desktop\WiFi" >NUL
netsh wlan export profile folder="%USERPROFILE%\Desktop\WiFi" key=clear
XCOPY "%~f0" "%USERPROFILE%\Desktop\WiFi\WiFi-Export.*" /F/R/Y
SET I="%USERPROFILE%\Desktop\WiFi\#ImportAll.cmd"
ECHO @ECHO OFF > %I%
ECHO COLOR 1F >>%I%
ECHO @ECHO. >>%I%
ECHO @ECHO I M P O R T I N G . . . >>%I%
ECHO @ECHO. >>%I%
ECHO FOR %%%%a in (.\*.xml) DO netsh wlan add profile filename="%%%%a" user=all >> %I%
ECHO @ECHO. >> %I%
ECHO PAUSE >> %I%

Domain verlassen

Save & rename to *.cmd:

:: RENAME domainUnjoin.cmd.txt to domainUnjoin.cmd
@echo off
color f0
echo.
SET title=Leaving Domain, joining WORKGROUP
title %title%
ECHO  [CAUTION!]
echo.
echo  %title%
echo.
PAUSE

powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "Remove-Computer -WorkgroupName 'WORKGROUP' -PassThru -Verbose -Restart"

shutdown.exe /r /t 5 /f
PAUSE

Domain beitreten

Save & rename to *.cmd:

:: RENAME domainJoin.cmd.txt to domainJoin.cmd
:: ADAPT Domain, AdminUsr, Password!
@echo off

SET Password=PaSsWoRd
SET AdminUsr=admin1
SET Domain  =schule-jegenstorf.ch

color f0
echo.
set title=Joining Domain "%Domain%"
title %title%
ECHO  [CAUTION!]
echo.
echo  %title%
echo.
PAUSE
REG ADD "HKLM\System\CurrentControlSet\Control\LSA" /v "NetJoinLegacyAccountReuse" /t REG_DWORD /d 1 /reg:64 /f >NUL

powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "Add-Computer -DomainName 'schule-jegenstorf.ch' -Credential (New-Object System.Management.Automation.PSCredential('schule-jegenstorf.ch\\admin1', (ConvertTo-SecureString 'pUt-PaSsWoRd' -AsPlainText -Force))) -Options JoinWithNewName -Force -Restart"

shutdown.exe /r /t 5 /f
PAUSE

DNS-Cache leeren

CMD (Admin!), dann
ipconfig /flushdns

Show Net Neighbors

Save & rename to *.cmd:

:: RENAME Show-NetNeighbors.cmd.txt to Show-NetNeighbors.cmd
@echo off
SET PS="%TEMP%\ShowNetNeighbor.ps1"
ECHO Get-NetNeighbor ^| Where-Object -Property state -ne Unreachable ^| where-object -property state -ne Permanent ^| Out-GridView -Title "Network Neighbors" -Wait > %PS%

powershell.exe -windowstyle hidden -ExecutionPolicy Bypass -Command %PS%

Show Printers

Save & rename to *.cmd:

:: RENAME Show-Printers.cmd.txt to Show-Printers.cmd
@echo off
SET PS="%TEMP%\ListPrinters.ps1"
ECHO Get-Printer ^| Out-GridView -Title "Printers (Select)" -PassThru ^| Out-GridView -Title "Selected Printers" -Wait > %PS%

powershell.exe -windowstyle hidden -ExecutionPolicy Bypass -Command %PS%

FOR-Schleife in BATCH

Save & rename to *.cmd:

:: RENAME doIt.cmd.txt to doIt.cmd
@echo off
set App=%ProgramW6432%\IrfanView\i_view64.exe
set folder="%USERPROFILE%\Pictures"
for %%f in ("%folder%\*.jpg") do (
  "%App%" "%%f"
)
pause

Windows ProductKey

Save & rename to *.cmd:

:: RENAME WindowsProductKey.cmd.txt to WindowsProductKey.cmd
@echo off
:: Check Privileges
NET FILE 1>NUL 2>NUL
IF "%errorlevel%"=="0" (goto gotPrivileges) else (goto getPrivileges)
:getPrivileges
if "%1"=="ELEV" (shift & goto gotPrivileges)
SETLOCAL DisableDelayedExpansion
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "Start-Process '%~dpnx0' ELEV -Verb runas"
goto :EOF
:gotPrivileges

echo.
set title=-= Windows Product Keys =-
title %title%
echo %title%
set PS1="%TEMP%\PK.ps1"
set OUT="C:\ProductKey.txt"
> %PS1% echo function Get-WindowsProductKey {
>> %PS1% echo $keyPath="HKLM:\SOFTWARE\Microsoft\Windows NT\CurrentVersion"
>> %PS1% echo try {
>> %PS1% echo $digitalProductId=(Get-ItemProperty -Path $keyPath -Name "DigitalProductId" -ErrorAction Stop).DigitalProductId
>> %PS1% echo $productName=(Get-ItemProperty -Path $keyPath -Name "ProductName" -ErrorAction Stop).ProductName
>> %PS1% echo } catch {
>> %PS1% echo Write-Warning "Einige Registry-Werte konnten nicht gelesen werden."
>> %PS1% echo $digitalProductId=$null
>> %PS1% echo $productName="Nicht gefunden"
>> %PS1% echo }
>> %PS1% echo $decodedKey=$null
>> %PS1% echo if ($digitalProductId) {
>> %PS1% echo $chars="BCDFGHJKMPQRTVWXY2346789"
>> %PS1% echo $keyOffset=52
>> %PS1% echo $decodedKey=""
>> %PS1% echo for ($i=24; $i -ge 0; $i--) {
>> %PS1% echo $current=0
>> %PS1% echo for ($j=14; $j -ge 0; $j--) {
>> %PS1% echo  $current=$current * 256 -bxor $digitalProductId[$j + $keyOffset]
>> %PS1% echo  $digitalProductId[$j + $keyOffset]=[math]::Floor($current / 24)
>> %PS1% echo  $current=$current %% 24
>> %PS1% echo }
>> %PS1% echo $decodedKey=$chars[$current] + $decodedKey
>> %PS1% echo if (($i %% 5) -eq 0 -and $i -ne 0) {
>> %PS1% echo  $decodedKey="-" + $decodedKey
>> %PS1% echo }
>> %PS1% echo }
>> %PS1% echo }
>> %PS1% echo try {
>> %PS1% echo $biosKey=(Get-WmiObject -query 'select * from SoftwareLicensingService').OA3xOriginalProductKey
>> %PS1% echo } catch {
>> %PS1% echo Write-Warning "OEM-Key konnte nicht aus dem BIOS gelesen werden."
>> %PS1% echo $biosKey=$null
>> %PS1% echo }
>> %PS1% echo if (Test-Path -Path %OUT% -PathType Leaf){Remove-Item -Path %OUT% -Force}
>> %PS1% echo $lines = @()
>> %PS1% echo $lines += "Windows Edition:      " + $productName
>> %PS1% echo if ($decodedKey) {
>> %PS1% echo  $lines += "Registry Product Key: " + $decodedKey
>> %PS1% echo } else {
>> %PS1% echo  $lines += "Registry Product Key: Nicht gefunden"
>> %PS1% echo }
>> %PS1% echo if ($biosKey) {
>> %PS1% echo  $lines += "OEM BIOS Key:         " + $biosKey
>> %PS1% echo } else {
>> %PS1% echo  $lines += "OEM BIOS Key:         Nicht gefunden"
>> %PS1% echo }
>> %PS1% echo foreach ($line in $lines) {
>> %PS1% echo  Write-Host $line
>> %PS1% echo  Add-Content -Path %OUT% -Value $line
>> %PS1% echo }
>> %PS1% echo ""
>> %PS1% echo Write-Host "Windows Product Keys saved to:" `"%OUT%`" +H +S +A
>> %PS1% echo }
>> %PS1% echo Get-WindowsProductKey
powershell.exe -NoLogo -ExecutionPolicy Bypass -File %PS1%
attrib +H +S +A %OUT% 2>NUL
:: del %PS1%
ECHO.
pause

Good Policies

Save & rename to *.reg:

Windows Registry Editor Version 5.00
; RENAME GoodPolicies.reg.txt to GoodPolicies.reg

; Proven good Windows settings
; (c) 2025-10-10 Thomas Bigler

; No OneDrive Known Folders Hijacking
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\OneDrive]
"KFMBlockOptIn"=dword:00000002

; No Bing Search suggestions
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows]
"AllowgameDVR"=dword:00000000
"DisableSearchBoxSuggestions"=dword:00000001

; Autorun Cleanup
[HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Run]
"XboxAppServices"=-
"AdobeCollabSync"=-

; No AppCompat-Service
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\AppCompat]
"DisablePCA"=dword:00000001

; No Consumer Ads
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\CloudContent]
"DisableWindowsConsumerFeatures"=dword:00000001
"DisableWindowsSpotlightFeatures"=dword:00000001
"DisableSoftLanding"=dword:00000001

[HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\AdvertisingInfo]
"DisabledByGroupPolicy"=dword:00000001

[HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\Personalization]
"NoLockScreen"=dword:00000001

[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Explorer]
"EnableLegacyBalloonNotifications"=dword:00000001
"NoNewAppAlert"=dword:00000001
"DisableNotificationCenter"=dword:00000001
"DisableSearchBoxSuggestions"=dword:00000001

; No Cortana
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Windows Search]
"AllowCortana"=dword:00000000

; Edge Policies
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Edge]
"PreventFirstRunPage"=dword:00000001
"RestoreOnStartup"=-
"NotificationsAllowed"=dword:00000000
"StandaloneHubsSidebarEnabled"=dword:00000000
"SleepingTabsEnabled"=dword:00000000
"LinkedAccountEnabled"=dword:00000000
"StartupBoostEnabled"=dword:00000000
"BackgroundModeEnabled"=dword:00000000
"WalletDonationEnabled"=dword:00000000
"WebWidgetAllowed"=dword:00000000
"ShowRecommendationsEnabled"=dword:00000000
"RelatedWebsiteSetsEnabled"=dword:00000000
"HideFirstRunExperience"=dword:00000001
"AllowGamesMenu"=dword:00000000
"RemoveDesktopShortcutDefault"=dword:00000001
"EdgeShoppingAssistantEnabled"=dword:00000000
"ShowAcrobatSubscriptionButton"=dword:00000000
"ShowPDFDefaultRecommendationsEnabled"=dword:00000000
"NewPDFReaderEnabled"=dword:00000000
"ShowMicrosoftRewards"=dword:00000000

; Edge Policies 2
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\MicrosoftEdge\Main]
"AllowPrelaunch"=dword:00000000

; No Extra Edge Link on Desktop
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\EdgeUpdate]
"CreateDesktopShortcutDefault"=dword:00000000

; Chrome Policies
[HKEY_LOCAL_MACHINE\Software\Policies\Google\Chrome]
"NotificationsAllowed"=dword:00000000

; Windows Copilot
; [HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsCopilot]
; "TurnOffWindowsCopilot"=dword:00000001

; No News Feed
[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\PolicyManager\default\NewsAndInterests\AllowNewsAndInterests]
"value"=dword:00000000
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Windows Feeds]
"EnableFeeds"=dword:00000000

; Pseudo Teams only on demand
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Windows Chat]
"ChatIcon"=dword:00000002
; "ChatIcon"=-

; No No OneDrive-Ads; TeamsChat=TaskbarMn, Widgets=TaskbarDa
[HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced]
"ShowSyncProviderNotifications"=dword:00000000
"HideFileExt"=dword:00000000
"TaskbarMn"=dword:00000002
"TaskbarDa"=-
; "TaskbarMn"=-

; IMPORTANT Settings for Current User
[KEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced]
"HideFileExt"=dword:00000000
"Filter"=dword:00000000
"Hideicons"=dword:00000000
"IntelliMenus"=dword:00000000
"FriendlyTree"=dword:00000000
"ShowCompColor"=dword:00000001
"MapNetDrvBtn"=dword:00000001
"PersistBrowsers"=dword:00000001
"DontPrettyPath"=dword:00000001
"FullPath"=dword:00000001
"FullPathAddress"=dword:00000001
"ListviewAlphaSelect"=dword:00000001
"EnableBalloonTips"=dword:00000001
"MultiTaskingAltTabFilter"=dword:00000003
"TaskbarMn"=dword:00000002

; Domain-PCs: PointAndPrint for Non-Admins
[HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows NT\Printers\PointAndPrint]
"RestrictDriverInstallationToAdministrators"=dword:00000000

; Domain-PCs: Accessible Shared Printers!
[HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\Print]
"RpcAuthnLevelPrivacyEnabled"=dword:00000000

; Domain-PCs: No OneDrive Folder Remapping
[HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\OneDrive]
"KFMBlockOptIn"=dword:00000002
; "KFMBlockOptIn"=-

; IMPORTANT Settings for Default Users
[HKEY_USERS\.DEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced]
"HideFileExt"=dword:00000000
"Filter"=dword:00000000
"Hideicons"=dword:00000000
"IntelliMenus"=dword:00000000
"FriendlyTree"=dword:00000000
"ShowCompColor"=dword:00000001
"MapNetDrvBtn"=dword:00000001
"PersistBrowsers"=dword:00000001
"DontPrettyPath"=dword:00000001
"FullPath"=dword:00000001
"FullPathAddress"=dword:00000001
"ListviewAlphaSelect"=dword:00000001
"EnableBalloonTips"=dword:00000001
"MultiTaskingAltTabFilter"=dword:00000003
"ShowSyncProviderNotifications"=dword:00000000
"TaskbarMn"=dword:00000002

; Current User Autorun Cleanup
[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run]
"PlanetVPN"=-
"com.squirrel.Teams.Teams"=-
"AdobeCollabSync"=-
"Adobe Acrobat Synchronizer"=-

MsEdge-Policies bereinigen

Save & rename to *.cmd:

:: RENAME MsEdge-Policies-Reset.cmd.txt to MsEdge-Policies-Reset.cmd
@ECHO OFF
:: Check Privileges
NET FILE 1>NUL 2>NUL
IF "%errorlevel%"=="0" (goto gotPrivileges) else (goto getPrivileges)
:getPrivileges
if "%1"=="ELEV" (shift & goto gotPrivileges)
SETLOCAL DisableDelayedExpansion
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "Start-Process '%~dpnx0' ELEV -Verb runas"
goto :EOF
:gotPrivileges

ECHO.
ECHO MsEdge wird bereinigt . . .
ECHO.
taskkill /im msedge.exe /f 2>NUL
reg delete "HKCU\Software\Policies\Microsoft\Edge" /f 2>NUL
reg delete "HKLM\Software\Policies\Microsoft\Edge" /f 2>NUL

SET REGNODE=/reg:64
SET EdgePol=HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Edge
REG ADD "%EdgePol%" /v "PreventFirstRunPage" /t REG_DWORD /d 1 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "HideFirstRunExperience" /t REG_DWORD /d 1 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "RemoveDesktopShortcutDefault" /t REG_DWORD /d 1 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "NotificationsAllowed" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "StandaloneHubsSidebarEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "SleepingTabsEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "LinkedAccountEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "StartupBoostEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "BackgroundModeEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "WalletDonationEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "WebWidgetAllowed" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "ShowRecommendationsEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "RelatedWebsiteSetsEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "RelatedWebsiteSetsEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "AllowGamesMenu" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "EdgeShoppingAssistantEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "ShowAcrobatSubscriptionButton" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "ShowPDFDefaultRecommendationsEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "NewPDFReaderEnabled" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
REG ADD "%EdgePol%" /v "ShowMicrosoftRewards" /t REG_DWORD /d 0 /f %REGNODE% 2>NUL
ECHO.
ECHO MsEdge ist wieder sauber!
ECHO.
pause

Uninstall Xbox & Teams Chat

Save & rename to *.cmd:

:: RENAME Uninst-Xbox&TeamsChat.cmd.txt to Uninst-Xbox&TeamsChat.cmd
@ECHO OFF
:: Check Privileges
NET FILE 1>NUL 2>NUL
IF "%errorlevel%"=="0" (goto gotPrivileges) else (goto getPrivileges)
:getPrivileges
if "%1"=="ELEV" (shift & goto gotPrivileges)
SETLOCAL DisableDelayedExpansion
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "Start-Process '%~dpnx0' ELEV -Verb runas"
goto :EOF
:gotPrivileges

SETLOCAL
@ECHO OFF
ECHO :: Disable Services: Xbox ^& Windows Media Player Network Sharing ::
ECHO.
SC stop XboxGipSvc 1>NUL 2>NUL
SC stop XblAuthManager 1>NUL 2>NUL
SC stop XboxNetApiSvc 1>NUL 2>NUL
SC stop XblGameSave 1>NUL 2>NUL
SC stop WMPNetworkSvc 1>NUL 2>NUL
SC config XboxGipSvc start= disabled
SC config XblAuthManager start= disabled
SC config XboxNetApiSvc start= disabled
SC config XblGameSave start= disabled
SC config WMPNetworkSvc start= disabled
ECHO.
SET PS="%TEMP%\UninstXboxTeamsChat.ps1"
ECHO Get-AppxPackage -AllUsers *MicrosoftTeams* ^| Remove-AppxPackage -ErrorAction SilentlyContinue > %PS%
ECHO Get-AppxPackage -AllUsers *XboxApp* ^| Remove-AppxPackage -ErrorAction SilentlyContinue >> %PS%
ECHO Get-AppxPackage -AllUsers *Microsoft.XboxGameOverlay* ^| Remove-AppxPackage -ErrorAction SilentlyContinue >> %PS%
ECHO Get-AppxPackage -AllUsers *Microsoft.XboxGamingOverlay* ^| Remove-AppxPackage -ErrorAction SilentlyContinue >> %PS%
ECHO Get-AppxPackage -AllUsers *Microsoft.Xbox.TCUI* ^| Remove-AppxPackage -ErrorAction SilentlyContinue >> %PS%
ECHO Get-AppxPackage -AllUsers *Microsoft.XboxApp* ^| Remove-AppxPackage -ErrorAction SilentlyContinue >> %PS%
ECHO Get-AppxPackage -AllUsers *Microsoft.GamingServices* ^| Remove-AppxPackage -ErrorAction SilentlyContinue >> %PS%
ECHO Get-AppxPackage -AllUsers *Microsoft.XboxIdentityProvider* ^| Remove-AppxPackage -ErrorAction SilentlyContinue >> %PS%
ECHO Get-AppxPackage -AllUsers *Microsoft.XboxSpeechToTextOverlay* ^| Remove-AppxPackage -ErrorAction SilentlyContinue >> %PS%
powershell.exe -ExecutionPolicy Bypass -Command %PS%
ECHO.
COLOR F0
ECHO Done.
ping -n 3 localhost >NUL
ENDLOCAL

Domain User ⇒ Local Admin

Save & rename to *.cmd:

:: RENAME DomUsr-LocalAdmin.cmd.txt to DomUsr-LocalAdmin.cmd
@echo off
:: Check Privileges
NET FILE 1>NUL 2>NUL
IF "%errorlevel%"=="0" (goto gotPrivileges) else (goto getPrivileges)
:getPrivileges
if "%1"=="ELEV" (shift & goto gotPrivileges)
SETLOCAL DisableDelayedExpansion
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "Start-Process '%~dpnx0' ELEV -Verb runas"
goto :EOF
:gotPrivileges
MODE CON: COLS=128 LINES=25
COLOR F1
SET DOM=%USERDNSDOMAIN%
SET ECHOLINE=ECHO  -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
SET TITLE=Add Domain-User to Local Group Administrators
TITLE %TITLE%
ECHO.
ECHO   %TITLE%
%ECHOLINE%
ECHO.
ECHO   Current Domain : %DOM%
ECHO.

if "%USERDNSDOMAIN%" LEQ "" (
ECHO   The computer must be joined to a domain!
ECHO.
goto DONE
)

set /p USR=^> Enter valid Domain-Username : 
if "%USR%" LEQ "" EXIT
net localgroup Administratoren %DOM%\%USR% /add
:Done
pause

Show Services

Save & rename to *.cmd:

:: RENAME Show-Services.cmd.txt to Show-Services.cmd
@echo off
SET PS="%TEMP%\ListServices.ps1"
ECHO Get-Service ^| Out-GridView -Title "Services" -PassThru > %PS%
powershell.exe -windowstyle hidden -ExecutionPolicy Bypass -Command %PS%

Energy Report

Save & rename to *.cmd:

:: RENAME Energy_Report.cmd.txt to Energy_Report.cmd
@echo off
NET FILE 1>NUL 2>NUL
IF "%errorlevel%"=="0" (goto gotPrivileges) else (goto getPrivileges)
:getPrivileges
if "%1"=="ELEV" (shift & goto gotPrivileges)
SETLOCAL DisableDelayedExpansion
SET P=ELEV
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "Start-Process '%~dpnx0' %P% -Verb runas"
goto :EOF
:gotPrivileges
ECHO Energy Report . . .
start /w powercfg.exe /batteryreport /output "%USERPROFILE%\Desktop\Power-Battery.html"
start file:///C:/Users/%USERNAME%/Desktop/Power-Battery.html
start /w powercfg.exe /systempowerreport /output "%USERPROFILE%\Desktop\Power-System.html"
start file:///C:/Users/%USERNAME%/Desktop/Power-System.html

UWP-Apps auflisten

Save & rename to *.cmd:

:: RENAME Show-UWP-Apps.cmd.txt to Show-UWP-Apps.cmd
@echo off
SET PS="%TEMP%\ListUwpApps.ps1"
ECHO Get-AppxProvisionedPackage -Online ^| Out-GridView -Title "UWP Apps" -PassThru > %PS%
powershell.exe -ExecutionPolicy Bypass -Command %PS%

Desktop-Links aller UWP-Apps

Save & rename to *.cmd:

:: RENAME UWP2Shortcut.cmd.txt to UWP2Shortcut.cmd
@echo off
SET PS="%TEMP%\Apps2Shortcut.ps1"

ECHO Function Create-Shortcut { > %PS%
ECHO   param ( >> %PS%
ECHO     [string]$name, >> %PS%
ECHO     [string]$aumid >> %PS%
ECHO   ) >> %PS%
ECHO   $WScriptShell = New-Object -ComObject WScript.Shell >> %PS%
ECHO   $Shortcut = $WScriptShell.CreateShortcut($name) >> %PS%
:: ECHO   $Shortcut.TargetPath = "$env:SystemRoot\explorer.exe" >> %PS%
:: ECHO   $Shortcut.Arguments = "shell:Appsfolder\$($aumid)" >> %PS%
ECHO   $Shortcut.Description  = "shell:Appsfolder\$($aumid)" >> %PS%
ECHO   $Shortcut.TargetPath = "shell:Appsfolder\$($aumid)" >> %PS%
ECHO   $Shortcut.Save() >> %PS%
ECHO } >> %PS%

ECHO $DesktopPath = [Environment]::GetFolderPath("Desktop") >> %PS%
ECHO. >> %PS%
ECHO if (!(Test-Path "$($DesktopPath)\UWP-Apps")) { >> %PS%
ECHO   New-Item "$($DesktopPath)\UWP-Apps" -ItemType Directory ^| Out-Null >> %PS%
ECHO } >> %PS%

ECHO $apps = (Get-StartApps) >> %PS%
ECHO for ($i = 0; $i -lt $apps.Count; $i++) { >> %PS%
ECHO   if (($apps[$i].AppID).contains("!") -and (($apps[$i].AppID).Substring(($apps[$i].AppID).Length - 4) -ne ".exe")) { >> %PS%
ECHO     Create-Shortcut "$($DesktopPath)\UWP-Apps\$($apps[$i].Name).lnk" $apps[$i].AppID  >> %PS%
ECHO   } >> %PS%
ECHO } >> %PS%

powershell.exe -windowstyle hidden -ExecutionPolicy Bypass -Command %PS%

Renew IP-Settings

Bei Verbindungsproblemen (Subnetzmaske od. Gateway falsch u.ä.)

ipconfig /flushdns
ipconfig /release
ipconfig /renew

Uninstall aus BATCH-Datei

MSI/UWP: CMD (Admin!), dann
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "Get-WmiObject -Class Win32_Product | Where-Object {$_.Name -like 'Microsoft.Xbox*'} | ForEach-Object {$_.Uninstall()}"

MSI/UWP: CMD (Admin!), dann
powershell.exe -NoProfile -ExecutionPolicy Bypass -Command "Get-WmiObject -Class Win32_Product | Where-Object {$_.Name -like 'Google Chrome*'} | ForEach-Object {$_.Uninstall()}"

Inno & others (Admin!)
START /W /D "%ProgramW6432%\Mozilla Firefox\uninstall" helper.exe /SILENT

Inno & others (Admin!)
START /W /D "%ProgramW6432%\OpenShot Video Editor" unins000.exe /SILENT

Show Drivers

Save & rename to *.cmd:

:: RENAME Show-Drivers.cmd.txt to Show-Drivers.cmd
@echo off
SET PS="%TEMP%\ListDrivers.ps1"
ECHO driverquery.exe /FO CSV ^| ConvertFrom-Csv ^| Out-GridView -Title "Installed Drivers" -Wait > %PS%

powershell.exe -windowstyle hidden -ExecutionPolicy Bypass -Command %PS%

List & Kill Process

Save & rename to *.cmd:

:: RENAME Kill-Process.cmd.txt to Kill-Process.cmd
@echo off
SET PS="%TEMP%\ListProcesses.ps1"
ECHO Get-Process ^| Sort-Object -Property CPU -Descending ^| Out-GridView -Title "Select Processe(s) to be killed" -PassThru ^| Stop-Process > %PS%

powershell.exe -windowstyle hidden -ExecutionPolicy Bypass -Command %PS%

Windows Version & Aktivierung

Save & rename to *.cmd:

:: RENAME Windows-Status.cmd.txt to Windows-Status.cmd
@echo off
echo.
set title=*** Windows Version, BackupProductKeyDefault ***
title %title%
echo %title%
SET OUTPUT="%USERPROFILE%\Desktop\KMS-Info.txt"
echo  %title% > %OUTPUT%
echo. >> %OUTPUT%
for /f "tokens=3*" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName 2^>nul') do (echo Productname^:  %%a %%b >> %OUTPUT%)
for /f "tokens=3*" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SoftwareProtectionPlatform" /v BackupProductKeyDefault 2^>nul') do (echo BUProductKey^: %%a %%b >> %OUTPUT%)
echo. >> %OUTPUT%
cscript //nologo "%SystemRoot%\System32\slmgr.vbs" /dlv >> %OUTPUT%
START NOTEPAD %OUTPUT%

MsOffice Version & Aktivierung

Save & rename to *.cmd:

:: RENAME MsOffice-Status.cmd.txt to MsOffice-Status.cmd
@echo off
echo.
echo  -= Microsoft Office Activation Status =-
echo.

SET PF=%ProgramFiles%
SET PF64=%ProgramW6432%
IF DEFINED ProgramFiles(x86) SET PF=%ProgramFiles(x86)%
SET MSO=Microsoft Office\Office16
SET OUTPUT="%USERPROFILE%\Desktop\MSO-Info.txt"
echo  -= Microsoft Office Activation Status =- > %OUTPUT%
echo. >> %OUTPUT%

SET OSPP=%PF%\%MSO%\ospp.vbs
if EXIST "%PF%\%MSO%\OSPP.VBS" (
ECHO   Installed: Microsoft Office x86 >> %OUTPUT%
CD "%PF%\%MSO%\"
GOTO DOIT
)

SET OSPP=%PF64%\%MSO%\ospp.vbs
if EXIST "%PF64%\%MSO%\OSPP.VBS" (
ECHO   Installed: Microsoft Office x64 >> %OUTPUT%
CD "%PF64%\%MSO%\"
GOTO DOIT
)

ECHO   Microsoft Office NOT FOUND! >> %OUTPUT%
ECHO. >> %OUTPUT%
:DOIT
ECHO.
cscript "%ospp%" /dstatus > mso.txt >> %OUTPUT%
START NOTEPAD %OUTPUT%